PHYS-1500 PHYSICAL MODELING
FALL 2006
Conservation of Mechanical Energy
The programs given here are based on the conservation of mechanical energy. In a system where
mechanical energy is conserved, and the potential energy is known, it is possible to find the
speed of an object in the system as a function of its position. With that information, it is possible
to deduce the position of the object as a function of time, in other words, to describe its motion.
dx
This is done by using the definition of velocity, v ( x ) 
. This can be rearranged to give,
dt
dx
, which tells the infinitesimal time, dt, that the object needs to travel the infinitesimal
dt 
v(x)
distance dx, at location x, where its velocity is v(x). Then these time intervals can be added, by
dx'
integration, to find how long the object takes to travel any finite distance: t  xx
. Actually,
v( x' )
this gives t as a function of x, but it is a simple matter to plot x as a function of t. We use
Simpson’s rule to do the integration. The trickiest detail is the method of dealing with the points
where v = 0. At those points, the integrand becomes infinite, so numerical methods of integration
fail. Instead, an approximate version of the integrand is integrated analytically at those points,
and added to the numerical results. Those analytic results are listed on the spreadsheets as “end
time”.
0
Two programs are given. The first is for the motion of a simple pendulum, but it is capable of
working at large angles. The second program deals with dropping an object from a great height
in a gravitational field. You have done problems similar to the second one, but not by this
method.
Pendulum Program
B4: =B5/B6
H4: =SQRT(H2/H3)
J5: =A210
D4: =B4*PI()/180
H5: =2*PI()/H4
D5: =B5*PI()/180
H6: =SQRT(2*D4/SIN(D5))/H4
A10: 0
A11: =A10+H10
B10: =D5
B11: =B10-$D$4
C10: =$H$4*SQRT(2*(COS(B10)-COS($D$5)))
C11: =$H$4*SQRT(2*(COS(B11)-COS($D$5)))
D10: =B10-$D$4/2
D11: =B11-$D$4/2
E10: =$H$4*SQRT(2*(COS(D10)-COS($D$5)))
E11: =$H$4*SQRT(2*(COS(D11)-COS($D$5)))
F10: =1/C10
F11: =1/C11
G10: =1/E10
G11: =1/E11
H10: =H6
H11: =$D$4*(F11+4*G11+F12)/6
I10: =$D$5*COS($H$4*A10)
I11: =$D$5*COS($H$4*A11)
Copy row 11 to rows 12 through row 111.
Then, the program needs corrections for “end time” and sign changes when it reaches its
midpoint. Change the following cells as indicated:
H109: =$H$6
D110: =B110+$D$4/2
H110: =$H$6
B111: =B110+$D$4
D111: =B111+$D$4/2
H111: =$D$4*(F111+4*G111+F112)/6
Now, copy row 111 to rows 112 through row 210.
Finally, a last end point correction. Change cell H209 to: =$H$6
Satellite Fall
B5: =D5-D6
D4: =B5/B6
H6: =D5*SQRT(2*D4/(H5*H4))
A10: 0
A11: =A10+H10
B10: =D5
B11: =B10-$D$4
C10: =-SQRT(2*$H$5*$H$4*(B10^-1-$D$5^-1))
C11: =-SQRT(2*$H$5*$H$4*(B11^-1-$D$5^-1))
D10: =B10-$D$4/2
D11: =B11-$D$4/2
E10: =-SQRT(2*$H$5*$H$4*(D10^-1-$D$5^-1))
E11: =-SQRT(2*$H$5*$H$4*(D11^-1-$D$5^-1))
F10: =1/C10
F11: =1/C11
G10: =1/E10
G11: =1/E11
H10: =H6
H11: =-$D$4*(F11+4*G11+F12)/6
Then, copy row 11 to rows 12 through 210.