S2-Mplus input files
1. Mplus input file for the model in Figure 1a
TITLE: MTMM model for interchangeable raters
Multilevel confirmatory factor model
with indicator-specific trait variables
for assessing teaching quality (model depicted in Figure 1a)
There are 3 constructs each measured by 3 items:
- STRUCTURE AND DIDACTIC QUALITY (measured by sd01-sd03)
- STIMULATION AND MOTIVATION (measured by sm01-sm03)
- APPLICATION-ORIENTED TEACHING (measured by ap01-ap03)
All lines beginning with an exclamation mark (!) represent comments
! Definition of the ASCII data file to be used
DATA: FILE = TRIL_neu.dat;
LISTWISE = ON;
! Definition of the variable names
VARIABLE: NAMES = v_code
sd01 sd02 sd03
sm08 sm09 sm10
ap21 ap22 ap24;
! Observed variables (items) to be used in the analysis
! Yrtik: r = method, t = target, i = indicator, k = trait
USEVARIABLES =
! Structure and didactic quality
! represent Yrt11, Yrt21, and Yrt31
sd01 sd02 sd03
! Stimulation and motivation
! represent Yrt12, Yrt22, and Yrt32
sm08 sm09 sm10
! Application-oriented teaching
! represent Yrt13, Yrt23, and Yrt33
ap21 ap22 ap24;
! Missing value flag
! all missing values are coded -99
MISSING = all(-99);
! Definition of the cluster variable
! This variable indicates the target (teacher)
CLUSTER = v_code;
! A twolevel CFA is requested using the following option
! This analysis includes the meanstructure of the variables
ANALYSIS: TYPE = TWOLEVEL;
information = expected;
! Model specification
MODEL:
! The following statements define the model to be estimated on level 1
! This is the level of the raters ("within" level)
! A common method factor is specified for each trait
! Mrt1 = method factor for structure and didactic quality
! Mrt2 = method factor for stimualtion and motivation
! Mrt3 = method factor for application-oriented teaching
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default
! in order to identify the model
! The remaining factor loadings are freely estimated
! Error variances for the observed variables are also estimated by default
%WITHIN%
Mrt1 by sd01 sd02 sd03;
Mrt2 by sm08 sm09 sm10;
Mrt3 by ap21 ap22 ap24;
! The means of the method factors have to be fixed to zero
[Mrt1@0];
[Mrt2@0];
[Mrt3@0];
! The following statements define the model to be estimated on level 2
! This is the level of the targets ("between" level)
! A trait variable is specified for each item (indicator-specific traits)
! Tt11, Tt21, and Tt31: trait variables for structure and didactic quality
! Tt12, Tt22, and Tt32: trait variables for stimulation and motivation
! Tt13, Tt23, and Tt33: trait variables for application oriented teaching
! The trait factor loadings are fixed to one
%BETWEEN%
Tt11 by sd01@1;
Tt21 by sd02@1;
Tt31 by sd03@1;
Tt12 by sm08@1;
Tt22 by sm09@1;
Tt32 by sm10@1;
Tt13 by ap21@1;
Tt23 by ap22@1;
Tt33 by ap24@1;
! The residual variances of the items are fixed to zero
! on the between level (they are estimated on the within level)
sd01@0;
sd02@0;
sd03@0;
sm08@0;
sm09@0;
sm10@0;
ap21@0;
ap22@0;
ap24@0;
! Sample statistics and the completely standardized solution are requested
OUTPUT: SAMPSTAT STANDARDIZED STDYX;
2. Mplus input file fort he model in Figure 1b
TITLE: MTMM model for interchangeable raters
Multilevel confirmatory factor model
with general trait factors (assuming homogeneous indicators)
for assessing teaching quality (model depicted in Figure 1b)
There are 3 constructs each measured by 3 items:
- STRUCTURE AND DIDACTIC QUALITY (measured by sd01-sd03)
- STIMULATION AND MOTIVATION (measured by sm08-sm10)
- APPLICATION-ORIENTED TEACHING (measured by ap21 ap22 ap24)
All lines beginning with an exclamation mark (!) represent comments
! Definition of the ASCII data file to be used
DATA: FILE = TRIL_neu.dat;
LISTWISE = ON;
! Definition of the variable names
VARIABLE: NAMES = v_code
sd01 sd02 sd03
sm08 sm09 sm10
ap21 ap22 ap24;
! Observed variables (items) to be used in the analysis
! Yrtik: r = method, t = target, i = indicator, k = trait
USEVARIABLES =
! Structure and didactic quality
! represent Yrt11, Yrt21, and Yrt31
sd01 sd02 sd03
! Stimulation and motivation
! represent Yrt12, Yrt22, and Yrt32
sm08 sm09 sm10
! Application-oriented teaching
! represent Yrt13, Yrt23, and Yrt33
ap21 ap22 ap24;
! Missing value flag
! all missing values are coded -99
MISSING = all(-99);
! Definition of the cluster variable
! This variable indicates the target (teacher)
CLUSTER = v_code;
! A twolevel CFA is requested using the following option
! This analysis includes the meanstructure of the variables
ANALYSIS: TYPE = TWOLEVEL;
information = expected;
! Model specification
MODEL:
! The following statements define the model to be estimated on level 1
! This is the level of the raters ("within" level)
! A method factor is specified for each trait
! Mrt1 = method factor for structure and didactic quality
! Mrt2 = method factor for stimualtion and motivation
! Mrt3 = method factor for application-oriented teaching
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default
! in order to identify the model.
! The remaining factor loadings are freely estimated
%WITHIN%
Mrt1 by sd01 sd02 sd03;
Mrt2 by sm08 sm09 sm10;
Mrt3 by ap21 ap22 ap24;
! The following statements define the model to be estimated on level 2
! This is the level of the targets ("between" level)
! All indicors Yrtik meaure indicator-specific trait variables Ttik
! That is, a trait variable is specified for each item (indicator-specific traits)
! Tt11, Tt21, and Tt31: trait variables for structure and didactic quality
! Tt12, Tt22, and Tt32: trait variables for stimulation and motivation
! Tt13, Tt23, and Tt33: trait variables for application oriented teaching
%BETWEEN%
Tt11 by sd01@1;
Tt21 by sd02@1;
Tt31 by sd03@1;
Tt12 by sm08@1;
Tt22 by sm09@1;
Tt32 by sm10@1;
Tt13 by ap21@1;
Tt23 by ap22@1;
Tt33 by ap24@1;
! In Model 1b, the trait variables Ttik are assumed
! to be unidimensional within the same trait
! That is, the trait variables Ttik are perfectly determined by
! general trait factors Ttk
! Tt1 = general trait factor for structure and didactic quality
! Tt2 = general trait factor for stimulation and motivation
! Tt3 = general trait factor for application oriented teaching
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default
! in order to identify the model.
! The remaining factor loadings are freely estimated
Tt1 by Tt11 Tt21 Tt31;
Tt2 by Tt12 Tt22 Tt32;
Tt3 by Tt13 Tt23 Tt33;
! The residual variances of the trait variables Ttik are set to zero
! as the trait variables are perfectly determined by the trait factors Ttk
Tt11-Tt33@0;
! The residual variances of the items are fixed to zero
! on the between level (they are estimated on the within level)
sd01@0;
sd02@0;
sd03@0;
sm08@0;
sm09@0;
sm10@0;
ap21@0;
ap22@0;
ap24@0;
! Sample statistics and the completely standardized solution are requested
OUTPUT: SAMPSTAT STANDARDIZED STDYX;
3. Mplus input file for the model in Figure 2
TITLE: MTMM model for structurally different raters
multiple indicator CTC(M-1) model with indicator-specific trait factors
depicted in Figure 2
There are 3 constructs.
Each construct has 3 indicators (item parcels) per method.
Hence there are 3 trait factors (Tik: i = indicator, k = trait) per trait:
- DEPRESSION (T11, T21, and T31)
- ANXIETY (T12, T22, and T32)
- COMPETENCE (T13, T23, and T33)
There are three methods:
- SELF REPORT (reference method, r = 1)
- TEACHER REPORT (non-reference method, r = 2)
- PARENT REPORT (non-reference method, r = 3)
There are three indicators (item parcels, Yrik) per trait-method unit
All lines beginning with an exclamation mark (!) are comments
! Definition of the ASCII data file to be used
DATA: FILE = cole.dat;
LISTWISE = ON;
! Definition of the observed variable names
! Yrik: r = method, i = indicator, k = trait
VARIABLE: NAMES = class school
! Depression self report
! represent Y111, Y121, and Y131
ds1 ds2 ds3
! Anxiety self report
! represent Y112, Y122, and Y132
as1 as2 as3
! Competence self report
! represent Y113, Y123, and Y133
cs1 cs2 cs3
! Depression teacher report
! represent Y211, Y221, and Y231
dt1 dt2 dt3
! Anxiety teacher report
! represent Y212, Y222, and Y232
at1 at2 at3
! Competence teacher report
! represent Y213, Y223, and Y233
ct1 ct2 ct3
! Depression parent report
! represent Y311, Y321, and Y331
dp1 dp2 dp3
! Anxiety parent report
! represent Y312, Y322, and Y332
ap1 ap2 ap3
! Competence parent report
! represent Y313, Y323, and Y333
cp1 cp2 cp3;
! Observed variables to be used in the analysis
USEVARIABLES ARE
ds1 ds2 ds3
as1 as2 as3
cs1 cs2 cs3
dt1 dt2 dt3
at1 at2 at3
ct1 ct2 ct3
dp1 dp2 dp3
ap1 ap2 ap3
cp1 cp2 cp3;
! Missing value flag
! all missing values are coded -9
MISSING ARE all(-9);
! Definition of the cluster variable
! (Children were nested within school classes)
CLUSTER IS class;
! A complex sample analysis is requested using the following option
! Under this option, a special robust ML estimator is used
! This robust ML estimator provides corrected standard errors and test statistics
! taking the multilevel structure and non-normality of the data into account
ANALYSIS: TYPE IS COMPLEX;
INFORMATION = expected;
MODEL: ! Construct Depression (k = 1)
! Indicator-specific trait factors (T11, T21, and T31)
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
T11 by ds1 dt1 dp1;
T21 by ds2 dt2 dp2;
T31 by ds3 dt3 dp3;
! Trait-specific method factors (Mrk: r = method, k = trait) depression
! The loading of the first indicator (marker indicator)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor M21: depression teacher report
M21 by dt1 dt2 dt3;
! Method factor M31: depression parent report
M31 by dp1 dp2 dp3;
! Method factors are defined as residual factors
! and are therefore not allowed to correlate
! with the trait factors belonging to the same trait
! the following commands constrain these correlations to zero
T11 with M21@0 M31@0;
T21 with M21@0 M31@0;
T31 with M21@0 M31@0;
! Construct Anxiety (k = 2)
! Indicator-specific trait factors (T12, T22, and T32)
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
T12 by as1 at1 ap1;
T22 by as2 at2 ap2;
T32 by as3 at3 ap3;
! Trait-specific method factors (Mrk: r = method, k = trait) anxiety
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor M22: anxiety teacher report
M22 by at1 at2 at3;
! Method factor M32: anxiety parent report
M32 by ap1 ap2 ap3;
! Method factors are defined as residual factors
! and are therefore not allowed to correlate
! with the trait factors belonging to the same trait
! the following commands constrain these correlations to zero
T12 with M22@0 M32@0;
T22 with M22@0 M32@0;
T32 with M22@0 M32@0;
! Construct Competence (k = 3)
! Indicator-specific trait factors (T13, T23, and T33)
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
T13 by cs1 ct1 cp1;
T23 by cs2 ct2 cp2;
T33 by cs3 ct3 cp3;
! Trait-specific method factors Mrk: r = method, k = trait) competence
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor M23: competence teacher report
M23 by ct1 ct2 ct3;
! Method factor M33: competence parent report
M33 by cp1 cp2 cp3;
! Method factors are defined as residual factors
! and are therefore not allowed to correlate
! with the trait factors belonging to the same trait
! the following commands constrain these correlations to zero
T13 with M23@0 M33@0;
T23 with M23@0 M33@0;
T33 with M23@0 M33@0;
! Sample statistics and the completely standardized solution are requested
! TECH4 provides the latent variable correlation matrix
OUTPUT: SAMPSTAT STANDARDIZED STDYX TECH4;
4. Mplus input file for a CTC(M-1) model with general trait factors
TITLE: MTMM model for structurally different raters
multiple indicator CTC(M-1) model with general trait factors
depicted in Figure 4 of Eid, Lischetzke, Nussbeck,
& Trierweiler (2003, Psychological Methods)
There are 3 constructs.
Each construct has 3 indicators (item parcels) per method.
There is 1 trait factor (Tk: k = trait) per trait:
- DEPRESSION (T1)
- ANXIETY (T2)
- COMPETENCE (T3)
There are three methods:
- SELF REPORT (reference method, r = 1)
- TEACHER REPORT (non-reference method, r = 2)
- PARENT REPORT (non-reference method, r = 3)
There are three indicators (item parcels, Yrik) per trait-method unit
All lines beginning with an exclamation mark (!) are comments
! Definition of the ASCII data file to be used
DATA: FILE = cole.dat;
LISTWISE = ON;
! Definition of the observed variable names
! Yrik: r = method, i = indicator, k = trait
VARIABLE: NAMES = class school
! Depression self report
! represent Y111, Y121, and Y131
ds1 ds2 ds3
! Anxiety self report
! represent Y112, Y122, and Y132
as1 as2 as3
! Competence self report
! represent Y113, Y123, and Y133
cs1 cs2 cs3
! Depression teacher report
! represent Y211, Y221, and Y231
dt1 dt2 dt3
! Anxiety teacher report
! represent Y212, Y222, and Y232
at1 at2 at3
! Competence teacher report
! represent Y213, Y223, and Y233
ct1 ct2 ct3
! Depression parent report
! represent Y311, Y321, and Y331
dp1 dp2 dp3
! Anxiety parent report
! represent Y312, Y322, and Y332
ap1 ap2 ap3
! Competence parent report
! represent Y313, Y323, and Y333
cp1 cp2 cp3;
! Observed variables to be used in the analysis
USEVARIABLES ARE
ds1 ds2 ds3
as1 as2 as3
cs1 cs2 cs3
dt1 dt2 dt3
at1 at2 at3
ct1 ct2 ct3
dp1 dp2 dp3
ap1 ap2 ap3
cp1 cp2 cp3;
! Missing value flag
! all missing values are coded -9
MISSING ARE all(-9);
! Definition of the cluster variable
! (Children were nested within school classes)
CLUSTER IS class;
! A complex sample analysis is requested using the following option
! Under this option, a special robust ML estimator is used
! This robust ML estimator provides corrected standard errors and test statistics
! taking the multilevel structure and non-normality of the data into account
ANALYSIS: TYPE IS COMPLEX;
INFORMATION = expected;
MODEL: ! Construct Depression (k = 1)
! General trait factor (T1)
! The loading of the first indicator (marker item)
! is fixed to one by default for identification
! The remaining factor loadings are freely estimated
T1 by ds1 ds2 ds3
dt1 dt2 dt3
dp1 dp2 dp3;
! Trait-specific method factors (Mrk: r = method, k = trait) depression
! The loading of the first indicator (marker indicator)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor M21: depression teacher report
M21 by dt1 dt2 dt3;
! Method factor M31: depression parent report
M31 by dp1 dp2 dp3;
! Method factors are defined as residual factors
! and are therefore not allowed to correlate
! with the trait factor belonging to the same trait
! the following command sets this correlation to zero
T1 with M21@0 M31@0;
! Construct Anxiety (k = 2)
! General trait factor (T2)
! The loading of the first indicator (marker item)
! is fixed to one by default for identification
! The remaining factor loadings are freely estimated
T2 by as1 as2 as3
at1 at2 at3
ap1 ap2 ap3;
! Trait-specific method factors (Mrk: r = method, k = trait) anxiety
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor M22: anxiety teacher report
M22 by at1 at2 at3;
! Method factor M32: anxiety parent report
M32 by ap1 ap2 ap3;
! Method factors are defined as residual factors
! and are therefore not allowed to correlate
! with the trait factor belonging to the same trait
! the following command sets this correlation to zero
T2 with M22@0 M32@0;
! Construct Competence (k = 3)
! Indicator-specific trait factors (T3)
! The loading of the first indicator (marker item)
! is fixed to one by default for identification
! The remaining factor loadings are freely estimated
T3 by cs1 cs2 cs3
ct1 ct2 ct3
cp1 cp2 cp3;
! Trait-specific method factors Mrk: r = method, k = trait) competence
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor M23: competence teacher report
M23 by ct1 ct2 ct3;
! Method factor M33: competence parent report
M33 by cp1 cp2 cp3;
! Method factors are defined as residual factors
! and are therefore not allowed to correlate
! with the trait factor belonging to the same trait
! the following command sets this correlation to zero
T3 with M23@0 M33@0;
! Sample statistics and the completely standardized solution are requested
! TECH4 provides the latent variable correlation matrix
OUTPUT: SAMPSTAT STANDARDIZED STDYX TECH4;
5. Mplus input file for the model in Figure 3a
TITLE: MTMM model for the combination of
interchangeable and structurally different raters
Version with indicator-specific trait variables
This model is depicted in Figure 3a
There are three mood constructs:
- PLEASANT-UNPLEASANTNESS (PU: Tt11rm-Tt31rm)
- AWAKE-SLEEPINESS (AS: Tt12rm-Tt32rm)
- CALM-RESTLESSNESS (CR: Tt13rm-Tt33rm)
There are three methods:
- SELF REPORT (r = 1, reference method)
- PEER REPORT 1 & 2 (r = 2)
The peer reports are interchangeable methods
Note: This model does not converge for this data set
due to the homogeneity of the indicators
! Definition of the ASCII data file to be used
DATA: FILE = mdbf.dat;
LISTWISE = ON;
! Definition of the observed variable names
VARIABLE: NAMES = ID SPU1 SPU2 SPU3 SAS1 SAS2 SAS3 SCR1 SCR2 SCR3
PPU1 PPU2 PPU3 PAS1 PAS2 PAS3 PCR1 PCR2 PCR3;
! Indicators to be used in the analysis
! Ytik(RM): t = target, i = indicator, k = trait, RM = reference method
! Ytik(NM): t = target, i = indicator, k = trait, NM = non-reference method
USEVARIABLES =
! Pleasant-Unpleasantness self-report
! these variables correspond to Yt11(RM), Yt21(RM), and Yt31(RM) in Fig. 3a
SPU1 SPU2 SPU3
! Awake-Sleepiness self-report
! these variables correspond to Yt12(RM), Yt22(RM), and Yt32(RM) in Fig. 3a
SAS1 SAS2 SAS3
! Calm-Restlessness self-report
! these variables correspond to Yt13(RM), Yt23(RM), and Yt33(RM) in Fig. 3a
SCR1 SCR2 SCR3
! Pleasant-Unpleasantness peer report
! these variables correspond to Yrt11(NM), Yrt21(NM), and Yrt31(NM) in Fig. 3a
PPU1 PPU2 PPU3
! Awake-Sleepiness peer report
! these variables correspond to Yrt12(NM), Yrt22(NM), and Yrt32(NM) in Fig. 3a
PAS1 PAS2 PAS3
! Calm-Restlessness peer report
! these variables correspond to Yrt13(NM), Yrt23(NM), and Yrt33(NM) in Fig. 3a
PCR1 PCR2 PCR3;
! Missing value flag
! all missing values are coded 999
MISSING ARE ALL (999);
! Definition of indicators that are used on level 2 only
! (indicators only used on the "between" level)
BETWEEN = SPU1 SPU2 SPU3 SAS1 SAS2 SAS3 SCR1 SCR2 SCR3;
! Definition of the cluster variable
! Peers are cluster within self-raters (ID)
Cluster IS ID;
! A twolevel CFA is requested using the following option
! This analysis includes the meanstructure of the variables
ANALYSIS:
TYPE IS TWOLEVEL;
INFORMATION = expected;
MITERATIONS = 50000;
ITERATIONS = 100000;
CONVERGENCE = 0.000050;
H1ITERATIONS = 10000;
H1CONVERGENCE = 0.000100;
! Model specification
MODEL:
! LEVEL 1
! The following statements define the model to be estimated on level 1
! This is the level of the raters ("within" level)
! A method factor [unique method factor UMrtk(NM)]is specified for each trait
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
%WITHIN%
! Method factor PLEASANT-UNPLEASANTNESS
UMrt1nm by PPU1 PPU2 PPU3;
! Method factor AWAKE-SLEEPINESS
UMrt2nm by PAS1 PAS2 PAS3;
! Method factor CALM-RESTLESSNESS
UMrt3nm by PCR1 PCR2 PCR3;
! LEVEL 2
! The following statements define the CT-C(M-1) model
! to be estimated on level 2
! This is the level of the targets ("between" level)
! There is a general trait factor Ttk(RM) for each construct
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
%BETWEEN%
! Indicator-specific trait variables Ttik(NM) for the non-reference method
! PLEASANT-UNPLEASANTNESS
Tt11nm by PPU1@1;
Tt21nm by PPU2@1;
Tt31nm by PPU3@1;
! AWAKE-SLEEPINESS
Tt12nm by PAS1@1;
Tt22nm by PAS2@1;
Tt32nm by PAS3@1;
! CALM-RESTLESSNESS
Tt13nm by PCR1@1;
Tt23nm by PCR2@1;
Tt33nm by PCR3@1;
! Indicator-specific trait factors Ttik(RM) pertaining to the reference method
! PLEASANT-UNPLEASANTNESS
! The asterisk (*) sets the loadings of Tt11nm, Tt21nm, and Tt31nm free
! These loadings would otherwise be fixed to unity by Mplus
Tt11rm by SPU1 Tt11nm*;
Tt21rm by SPU2 Tt21nm*;
Tt31rm by SPU3 Tt31nm*;
! AWAKE-SLEEPINESS
Tt12rm by SAS1 Tt12nm*;
Tt22rm by SAS2 Tt22nm*;
Tt32rm by SAS3 Tt32nm*;
! CALM-RESTLESSNESS
Tt13rm by SCR1 Tt13nm*;
Tt23rm by SCR2 Tt23nm*;
Tt33rm by SCR3 Tt33nm*;
! Trait-specific method factors CMtk(NM) on level 2
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor PLEASANT-UNPLEASANTNESS
CMt1nm by Tt11nm Tt21nm Tt31nm;
! Method factor AWAKE-SLEEPINESS
CMt2nm by Tt12nm Tt22nm Tt32nm;
! Method factor CALM-RESTLESSNESS
CMt3nm by Tt13nm Tt23nm Tt33nm;
! Residual variances of the trait variables Ttik(nm) are set to zero
! as the trait variables are assumed to be homogeneous
Tt11nm@0;
Tt21nm@0;
Tt31nm@0;
Tt12nm@0;
Tt22nm@0;
Tt32nm@0;
Tt13nm@0;
Tt23nm@0;
Tt33nm@0;
! Correlations between trait factors Ttik(RM) and Common Method Factors CMtk(NM)
! belonging to the same trait-method unit are set to zero
Tt11rm Tt21rm Tt31rm with CMt1nm@0;
Tt12rm Tt22rm Tt32rm with CMt2nm@0;
Tt13rm Tt23rm Tt33rm with CMt3nm@0;
! The residual variances of the non-reference items are fixed to zero
! on the between level (they are estimated on the within level)
PPU1@0;
PPU2@0;
PPU3@0;
PAS1@0;
PAS2@0;
PAS3@0;
PCR1@0;
PCR2@0;
PCR3@0;
! Sample statistics and the completely standardized solution are requested
OUTPUT: SAMPSTAT STANDARDIZED STDYX;
6. Mplus input files for the model in Figure 3b
TITLE: MTMM model for the combination of
interchangeable and structurally different raters
Version with general trait factors
This model is depicted in Figure 3b
There are three mood constructs:
- PLEASANT-UNPLEASANTNESS (PU: Tt1rm)
- AWAKE-SLEEPINESS (AS: Tt2rm)
- CALM-RESTLESSNESS (CR: Tt3rm)
There are three methods:
- SELF REPORT (r = 1, reference method)
- PEER REPORT 1 & 2 (r = 2)
The peer reports are interchangeable methods
! Definition of the ASCII data file to be used
DATA: FILE = mdbf.dat;
LISTWISE = ON;
! Definition of the observed variable names
VARIABLE: NAMES = ID SPU1 SPU2 SPU3 SAS1 SAS2 SAS3 SCR1 SCR2 SCR3
PPU1 PPU2 PPU3 PAS1 PAS2 PAS3 PCR1 PCR2 PCR3;
! Indicators to be used in the analysis
! Ytik(RM): t = target, i = indicator, k = trait, RM = reference method
! Ytik(NM): t = target, i = indicator, k = trait, NM = non-reference method
USEVARIABLES =
! Pleasant-Unpleasantness self-report
! these variables correspond to Yt11(RM), Yt21(RM), and Yt31(RM) in Fig. 3b
SPU1 SPU2 SPU3
! Awake-Sleepiness self-report
! these variables correspond to Yt12(RM), Yt22(RM), and Yt32(RM) in Fig. 3b
SAS1 SAS2 SAS3
! Calm-Restlessness self-report
! these variables correspond to Yt13(RM), Yt23(RM), and Yt33(RM) in Fig. 3b
SCR1 SCR2 SCR3
! Pleasant-Unpleasantness peer report
! these variables correspond to Yrt11(NM), Yrt21(NM), and Yrt31(NM) in Fig. 3b
PPU1 PPU2 PPU3
! Awake-Sleepiness peer report
! these variables correspond to Yrt12(NM), Yrt22(NM), and Yrt32(NM) in Fig. 3b
PAS1 PAS2 PAS3
! Calm-Restlessness peer report
! these variables correspond to Yrt13(NM), Yrt23(NM), and Yrt33(NM) in Fig. 3b
PCR1 PCR2 PCR3;
! Missing value flag
! all missing values are coded 999
MISSING ARE ALL (999);
! Definition of indicators that are used on level 2 only
! (indicators only used on the "between" level)
BETWEEN = SPU1 SPU2 SPU3 SAS1 SAS2 SAS3 SCR1 SCR2 SCR3;
! Definition of the cluster variable
! Peers are cluster within self-raters (ID)
Cluster IS ID;
! A twolevel CFA is requested using the following option
! This analysis includes the meanstructure of the variables
ANALYSIS:
TYPE IS TWOLEVEL;
INFORMATION = expected;
MITERATIONS = 50000;
ITERATIONS = 100000;
CONVERGENCE = 0.000050;
H1ITERATIONS = 10000;
H1CONVERGENCE = 0.000100;
! Model specification
MODEL:
! LEVEL 1
! The following statements define the model to be estimated on level 1
! This is the level of the raters ("within" level)
! A method factor [unique method factor UMrtk(NM)] is specified for each trait
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
%WITHIN%
! Method factor PLEASANT-UNPLEASANTNESS
UMrt1nm by PPU1 PPU2 PPU3;
! Method factor AWAKE-SLEEPINESS
UMrt2nm by PAS1 PAS2 PAS3;
! Method factor CALM-RESTLESSNESS
UMrt3nm by PCR1 PCR2 PCR3;
! LEVEL 2
! The following statements define the CT-C(M-1) model
! to be estimated on level 2
! This is the level of the targets ("between" level)
! There is a general trait factor Ttk(RM) for each construct
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
%BETWEEN%
! Indicator-specific trait variables Ttik(NM) for the non-reference method
! PLEASANT-UNPLEASANTNESS
Tt11nm by PPU1@1;
Tt21nm by PPU2@1;
Tt31nm by PPU3@1;
! AWAKE-SLEEPINESS
Tt12nm by PAS1@1;
Tt22nm by PAS2@1;
Tt32nm by PAS3@1;
! CALM-RESTLESSNESS
Tt13nm by PCR1@1;
Tt23nm by PCR2@1;
Tt33nm by PCR3@1;
! Trait factors Ttk(RM) belonging to the reference method
! The asterisk (*) sets the loadings of Tt11nm, Tt12nm, and Tt13nm free
! These loadings would otherwise be fixed to unity by Mplus as
! the indicators are latent factors
Tt1rm by SPU1 SPU2 SPU3 Tt11nm* Tt21nm Tt31nm;
! Trait factor AWAKE-SLEEPINESS
Tt2rm by SAS1 SAS2 SAS3 Tt12nm* Tt22nm Tt32nm;
! Trait factor CALM-RESTLESSNESS
Tt3rm by SCR1 SCR2 SCR3 Tt13nm* Tt23nm Tt33nm;
! Residual variances of the trait variables Ttik are set to zero
! as the trait variables are assumed to be homogeneous
Tt11nm-Tt33nm@0;
! Trait-specific method factors CMtk(NM) on level 2
! The loading of the first indicator (marker item)
! is fixed to one for each factor by default for identification
! The remaining factor loadings are freely estimated
! Method factor PLEASANT-UNPLEASANTNESS
CMt1nm by Tt11nm Tt21nm Tt31nm;
! Method factor AWAKE-SLEEPINESS
CMt2nm by Tt12nm Tt22nm Tt32nm;
! Method factor CALM-RESTLESSNESS
CMt3nm by Tt13nm Tt23nm Tt33nm;
! Correlations between Traits and Common Method Factors
! belonging to the same trait-method unit are set to zero
Tt1rm with CMt1nm@0;
Tt2rm with CMt2nm@0;
Tt3rm with CMt3nm@0;
! The residual variances of the non-reference items are fixed to zero
! on the between level (they are estimated on the within level)
PPU1@0;
PPU2@0;
PPU3@0;
PAS1@0;
PAS2@0;
PAS3@0;
PCR1@0;
PCR2@0;
PCR3@0;
! Sample statistics and the completely standardized solution are requested
OUTPUT: SAMPSTAT STANDARDIZED STDYX;