//*************************************************************
// script for designing the CAD geometry and mesh for vanes
// of varying inclines to flow direction for vortex generation
//*************************************************************
//----------------------------------------------------------------------
// parameters controlling mesh sizing
// hIn: parametrizes element sizes close to the vortex generator vane
// hOut: parametrizes element sizes away from the vortex generator vane
//-----------------------------------------------------------------------
hIn = 0.1;
hOut = 0.2;
//-------------------------------------------------------
// parameters controlling the channel containing the vane
// this is the flow domain
//-------------------------------------------------------
channelLength = 6.00;
channelWidth = 3.00;
channelHeight = 3.00;
//--------------------------------------------------------
// parameters controlling the geometry of the vane for the
// vortex generator
//--------------------------------------------------------
vaneLength = 1.00;
vaneWidth = 0.50;
vaneHeight = 1.50;
vaneAngle = 0.00;
//-------------------------------------------------------------------
// reference coordinates identifying the position of the four corners
// on the bottom plane where the vane is attached
// P1 = (vaneFrontX, vaneRightX)
// P2 = (vaneFrontX, vaneLeftY)
// P3 = (vaneBackX, vaneLeftY)
// P4 = (vaneBackX, vaneRightY)
//-------------------------------------------------------------------
vaneFrontX = 0.5*channelLength - 0.5*vaneLength;
vaneBackX = 0.5*channelLength + 0.5*vaneLength;
vaneLeftY = 0.5*channelWidth - 0.5*vaneWidth;
vaneRightY = 0.5*channelWidth + 0.5*vaneWidth;
//--------------------------------------------------------------------
// coordinate transformation to account for a vane orientation that is
// inclined to the longitudinal direction of the channel
//--------------------------------------------------------------------
vane_1_x = 0.5*channelLength + (vaneFrontX-0.5*channelLength)*Cos(vaneAngle) - (vaneRightY-0.5*channelWidth)*Sin(vaneAngle);
vane_1_y = 0.5*channelWidth + (vaneFrontX-0.5*channelLength)*Sin(vaneAngle) + (vaneRightY-0.5*channelWidth)*Cos(vaneAngle);
vane_2_x = 0.5*channelLength + (vaneFrontX-0.5*channelLength)*Cos(vaneAngle) - (vaneLeftY-0.5*channelWidth)*Sin(vaneAngle);
vane_2_y = 0.5*channelWidth + (vaneFrontX-0.5*channelLength)*Sin(vaneAngle) + (vaneLeftY-0.5*channelWidth)*Cos(vaneAngle);
vane_3_x = 0.5*channelLength + (vaneBackX-0.5*channelLength)*Cos(vaneAngle) - (vaneRightY-0.5*channelWidth)*Sin(vaneAngle);
vane_3_y = 0.5*channelWidth + (vaneBackX-0.5*channelLength)*Sin(vaneAngle) + (vaneRightY-0.5*channelWidth)*Cos(vaneAngle);
vane_4_x = 0.5*channelLength + (vaneBackX-0.5*channelLength)*Cos(vaneAngle) - (vaneLeftY-0.5*channelWidth)*Sin(vaneAngle);
vane_4_y = 0.5*channelWidth + (vaneBackX-0.5*channelLength)*Sin(vaneAngle) + (vaneLeftY-0.5*channelWidth)*Cos(vaneAngle);
//---------------------------------------------------------
// specify all the control points for the overall geometry
// of the flow domain
//---------------------------------------------------------
Point(1) = {0.0, 0.0, 0.0, hOut};
Point(2) = {0.0, channelWidth, 0.0, hOut};
Point(3) = {channelLength, channelWidth, 0.0, hOut};
Point(4) = {channelLength, 0.0, 0.0, hOut};
Point(5) = {0.0, 0.0, channelHeight, hOut};
Point(6) = {0.0, channelWidth, channelHeight, hOut};
Point(7) = {channelLength, channelWidth, channelHeight, hOut};
Point(8) = {channelLength, 0.0, channelHeight, hOut};
Point(9) = {vane_1_x, vane_1_y, 0.0, hIn};
Point(10)= {vane_2_x, vane_2_y, 0.0, hIn};
Point(11)= {vane_4_x, vane_4_y, 0.0, hIn};
Point(12)= {vane_3_x, vane_3_y, 0.0, hIn};
//Point(13)= {vane_1_x, vane_1_y, vaneHeight, hIn};
//Point(14)= {vane_2_x, vane_2_y, vaneHeight, hIn};
Point(15)= {vane_4_x, vane_4_y, vaneHeight, hIn};
Point(16)= {vane_3_x, vane_3_y, vaneHeight, hIn};
//-------------------------------------------------------
// specify all the lines and curves defining the geometry
//-------------------------------------------------------
Line(1) = {6, 5};
Line(2) = {5, 1};
Line(3) = {1, 2};
Line(4) = {2, 6};
Line(5) = {1, 4};
Line(6) = {4, 8};
Line(7) = {8, 7};
Line(8) = {7, 3};
Line(9) = {3, 2};
Line(10) = {6, 7};
Line(11) = {5, 8};
Line(12) = {10, 9};
//Line(13) = {9, 13};
//Line(14) = {13, 14};
Line(14) = {15,10}; //--------------------------------
//Line(15) = {14, 10};
//Line(16) = {13, 16};
Line(16) = {16,9}; //--------------------------------
Line(17) = {16, 15};
//Line(18) = {15, 14};
Line(19) = {15, 11};
Line(20) = {16, 12};
Line(21) = {11, 12};
Line(22) = {12, 9};
Line(23) = {11, 10};
Line(26) = {3, 4};
//-----------------------------------------------
// specify all the surfaces defining the geometry
//-----------------------------------------------
Line Loop(24) = {10, -7, -11, -1};
Plane Surface(25) = {24};
Line Loop(27) = {4, 1, 2, 3};
Plane Surface(28) = {27};
Line Loop(29) = {6, 7, 8, 26};
Plane Surface(30) = {29};
Line Loop(31) = {-16, 20, 22};
Plane Surface(32) = {31};
Line Loop(33) = {-12, -14, -17, 16};
Plane Surface(34) = {33};
Line Loop(35) = {20, -21, -19, -17};
Plane Surface(36) = {35};
//Line Loop(37) = {14, 15, 12, 13};
//Plane Surface(38) = {37};
Line Loop(39) = {14, -23, -19};
Plane Surface(40) = {39};
Line Loop(41) = {10, 8, 9, 4};
Plane Surface(42) = {41};
Line Loop(43) = {11, -6, -5, -2};
Plane Surface(44) = {43};
Line Loop(45) = {5, -26, 9, -3};
Line Loop(46) = {22, -12, -23, 21};
Plane Surface(47) = {45, 46};
//-------------------------------------------------
// specify all the volumes defining the flow domain
//-------------------------------------------------
Surface Loop(48) = {25, 42, 30, 44, 47, 28, 36, 32, 34, 40};
Volume(49) = {48};
//--------------------------------------------------------
// specify all the marker ids for the surfaces and volumes
//--------------------------------------------------------
Physical Surface(50) = {25};
Physical Surface(51) = {28};
Physical Surface(52) = {44};
Physical Surface(53) = {30};
Physical Surface(54) = {42};
Physical Surface(55) = {47};
Physical Surface(56) = {32, 34, 36, 40};
Physical Volume(57) = {49};