PHYS-1500 PHYSICAL MODELING
FALL 2006
Still More of the Rocket in Orbit Program
Below is a copy of the program for the rocket in orbit. This program will take a rocket from a
low circular orbit to a higher orbit. Below the pictures of the spreadsheet are the contents of the
cells. For the cells above the actual program, i.e. rows 1 through 11, only the contents of the cells
containing formulae have been given. For rows 12 and 13, the contents of all cells have been
given. When row 13 is complete, the entire row (except cell K13) should be copied to rows 14
through 513. Then, use the program to answer the questions on the assignment sheet.
D6: =J7*SQRT(1/(1+B5/B6))
D7: =MIN(O12:O513)
A12: 0
A13: =A12+Q12
G5: =J6
G6: =B5*G5
G7: =G5^2/2-B3*B4/B5
G8: =-B3*B4/(2*B6)
B12: =B5
B13: =B12+E12*Q12
D12: =-$B$3*$B$4/B12^2+M12^2/B12^3
D13: =-$B$3*$B$4/B13^2+M13^2/B13^3
G12: 0
G13: =G12+(H13)*Q12
H12: =M12/B12^2
H13: =M13/B13^2
J3: =MAX(B12:B513)
J4: =MIN(B12:B213)
J5: =MAX(T12:T513)
J6: =SQRT(B3*B4/B5)
J7: =SQRT(2)*J6
J8: =SQRT(B3*B4/B6)
J9: =MAX(R12:R513)
C12: 0
C13: =E12
E12: =C12+D12*Q12
E13: =C13+D13*Q13
F12: =IF(E12<0,-1,1)
F13: =IF(E13<0,-1,1)
I12: =B12*COS(G12) J12: =B12*SIN(G12)
I13: =B13*COS(G13) J13: =B13*SIN(G13)
K12: =AVERAGE(J3:J4)
K13: =-K12
Turn the paper over. There is more on the back
L12: =$G$7
L13: =L12+P12*B12*H12*Q12/O12
M12: =B12*SQRT(2*(L12+$B$3*$B$4/B12)-C12^2)
M13: =B13*SQRT(2*(L13+$B$3*$B$4/B13)-C13^2)
N12: 0
N13: =1/($B$3*$B$4/M13^2-SQRT(($B$3*$B$4/M13^2)^2+2*L13/M13^2))
O12: =$B$7
O13: =IF(P12=0,O12,O12-$B$8*Q12)
P12: =IF(N12<$B$6,$B$8*$B$9,IF(AND(B12>$B$6,L12<$G$8),$B$8*$B$9,0))
P13: =IF(N13<$B$6,$B$8*$B$9,IF(AND(B13>$B$6,L13<$G$8),$B$8*$B$9,0))
Q12: =IF(P12>0,$G$3*(O12/$B$7)^$G$4,$G$3)
Q13: =IF(P13>0,$G$3*(O13/$B$7)^$G$4,$G$3)
R12: =P12/O12
R13: =P13/O13
S12: =SQRT(C12^2+(B12*H12)^2)
S13: =SQRT(C13^2+(B13*H13)^2)
T12: =IF(P12<P11,A12)
T13: =IF(P13<P12,A13)